读写AT93C46的精练代码

以下代码经调试通过。代码少，晶振为11.0592的。贡献给有需要的朋友们。
适但修改一下时钟周期和地址位数便可用于AT93CXX的其它型号。

;AT93C46的汇编读写软件包
;----------------------------------------------------------------------------
CS_93C46 EQU P2.7 ;片选
SK_93C46 EQU P2.6 ;时钟
DI_93C46 EQU P2.5 ;数据输入
DO_93C46 EQU P2.4 ;数据输出
DATA_HIGH DATA 30H ;待写数据高位
DATA_LOW DATA 31H ;待写数据高位
DATA_ADDRESS DATA 32H ;待读或写的地址
;******************************************************************
;名称:读指令(READ指令)
;功能:把93C46中DATA_ADDRESS所指向的地址单元的数据
; 读到DATA_HIGH(H),DATA_LOW(L)中。
;******************************************************************
READ_93C46:
CLR EA
SETB CS_93C46
MOV A,DATA_ADDRESS
ORL A,#80H ;读操作码10A5A4A3A2A1A0B
SETB C ;产生启始条件。
MOV R6,#09H
READ1:
CLR SK_93C46
MOV DI_93C46,C
SETB SK_93C46
RLC A
DJNZ R6,READ1

MOV R6,#09H ;连续读取两个字节的数据加一位伪数据位。
READ2:
CLR SK_93C46
SETB DO_93C46
MOV C,DO_93C46
SETB SK_93C46
RLC A
DJNZ R6,READ2
MOV DATA_HIGH,A
MOV R6,#08H
READ3:
CLR SK_93C46
SETB DO_93C46
MOV C,DO_93C46
SETB SK_93C46
RLC A
DJNZ R6,READ3
MOV DATA_LOW, A
CLR SK_93C46
CLR CS_93C46
CLR DI_93C46
CLR DO_93C46
SETB EA
RET

;******************************************************************
;名称:写指令(WRITE指令)
;功能:把DATA_HIGH(H),DATA_LOW(L)的数据
; 写到93C46中DATA_ADDRESS所指向的存储器中
;******************************************************************
WRITE_93C46:
CLR EA
SETB DI_93C46
SETB CS_93C46
MOV A, #30H ;写允许操作码0011XXXXB
SETB C
MOV R6, #09H
WRIT1:
CLR SK_93C46
MOV DI_93C46, C
SETB SK_93C46
RLC A
DJNZ R6, WRIT1
CLR CS_93C46

NOP
MOV A,DATA_ADDRESS ;送入写操作码和地址。
ORL A,#40H
SETB CS_93C46
SETB C
MOV R6,#09H
WRIT3:
CLR SK_93C46
MOV DI_93C46,C
SETB SK_93C46
RLC A
DJNZ R6,WRIT3

MOV R6,#08H ;写入高八位。
MOV A,DATA_HIGH
WRIT4:
CLR SK_93C46
RLC A
MOV DI_93C46,C
NOP
SETB SK_93C46
NOP
DJNZ R6,WRIT4

MOV R6,#08H ;写入低八位。
MOV A,DATA_LOW
WRIT5:
CLR SK_93C46
RLC A
MOV DI_93C46,C
NOP
SETB SK_93C46
NOP
DJNZ R6,WRIT5
SETB DO_93C46
CLR CS_93C46
NOP
SETB CS_93C46
JNB DO_93C46,$ ;检测就绪状态。
CLR CS_93C46

SETB CS_93C46
MOV A,#00H ;写禁止操作码0000XXXXB
SETB C
MOV R6,#09H
WRIT6:
CLR SK_93C46
MOV DI_93C46,C
RLC A
SETB SK_93C46
NOP
DJNZ R6,WRIT6

CLR CS_93C46
CLR SK_93C46
CLR DI_93C46
CLR DI_93C46
SETB EA
RET